Setup publication process

Author: stefan-ka

.travis.yml

@@ -5,7 +5,16 @@ jdk:
 
 install: "/bin/true"
 
-script: ./gradlew clean build snapshot
+script:
+  - |
+    if [[ $TRAVIS_TAG =~ ^v.* ]]; then
+      ./gradlew clean build publish -Prelease.useLastTag=true -Psigning.keyId=${GPG_KEY_ID} -Psigning.password=${GPG_KEY_PASSPHRASE}
+    else
+      ./gradlew clean build snapshot $(if [[ $TRAVIS_BRANCH == "master" && $TRAVIS_PULL_REQUEST == 'false' ]]; then echo "publish -Psigning.keyId=${GPG_KEY_ID} -Psigning.password=${GPG_KEY_PASSPHRASE}"; fi)
+    fi
+
+before_install:
+- openssl aes-256-cbc -K $encrypted_6dfdcbc02577_key -iv $encrypted_6dfdcbc02577_iv -in secret-key.gpg.enc -out secret-key.gpg -d
 
 after_success:
 - bash <(curl -s https://codecov.io/bash)

build.gradle

@@ -2,6 +2,8 @@ plugins {
     id 'java'
     id 'jacoco'
     id 'nebula.release' version '13.0.0'
+    id 'maven-publish'
+    id 'signing'
 }
 
 group 'io.github.stefan-ka'
@@ -13,6 +15,10 @@ repositories {
     mavenCentral()
 }
 
+if (!project.hasProperty('signing.secretKeyRingFile')) {
+    project.ext.'signing.secretKeyRingFile' = "${rootDir}/secret-key.gpg"
+}
+
 dependencies {
     implementation group: 'org.freemarker', name: 'freemarker', version: freemarkerVersion
 
@@ -21,6 +27,119 @@ dependencies {
     testRuntimeOnly group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: jUnitVersion
 }
 
+task sourcesJar(type: Jar) {
+    from sourceSets.main.allJava
+    archiveClassifier = 'sources'
+}
+
+task javadocJar(type: Jar) {
+    from javadoc
+    archiveClassifier = 'javadoc'
+}
+
+artifacts {
+    archives javadocJar, sourcesJar
+}
+
+signing {
+    sign configurations.archives
+    required { gradle.taskGraph.hasTask("publishMavenJavaPublicationToMavenLocal") || gradle.taskGraph.hasTask("publishMavenJavaPublicationToMavenRepository") }
+}
+
+publishing {
+    publications {
+        mavenJava(MavenPublication) {
+            customizePom(pom)
+
+            artifactId = "${project.name}"
+            groupId = "${project.group}"
+            version = "${project.version}"
+            from components.java
+            artifact sourcesJar
+            artifact javadocJar
+
+            pom.withXml {
+                def pomFile = file("${project.buildDir}/generated-pom.xml")
+                writeTo(pomFile)
+                def pomAscFile = signing.sign(pomFile).signatureFiles[0]
+                artifact(pomAscFile) {
+                    classifier = null
+                    extension = 'pom.asc'
+                }
+            }
+
+            signArchives.signatures.each { signature ->
+                artifact(signature) {
+                    def matcher = signature.file =~ /-(sources|javadoc)\.jar\.asc$/
+                    if (matcher.find()) {
+                        classifier = matcher.group(1)
+                    } else {
+                        classifier = null
+                    }
+                    extension = signature.type
+                }
+            }
+        }
+    }
+    repositories {
+        maven {
+            def releasesRepoUrl = "${ossReleaseStagingRepository}"
+            def snapshotsRepoUrl = "${ossSnapshotRepository}"
+            url = project.version.toString().endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
+
+            credentials {
+                username = System.getenv('OSSRH_USERNAME')
+                password = System.getenv('OSSRH_PASSWORD')
+            }
+        }
+    }
+}
+
+def customizePom(pom) {
+    pom.withXml {
+        def root = asNode()
+
+        // eliminate test-scoped dependencies
+        root.dependencies.removeAll { dep ->
+            dep.scope == "test"
+        }
+
+        root.children().last() + {
+            resolveStrategy = Closure.DELEGATE_FIRST
+
+            description 'A Java Library to Generate/Serialize Protocol Buffer Files (*.proto files)'
+            name 'protobufgen'
+            url 'https://github.com/stefan-ka/protobufgen'
+            organization {
+                name 'Stefan Kapferer'
+                url 'https://stefan.kapferer.ch/'
+            }
+            issueManagement {
+                system 'GitHub'
+                url 'https://github.com/stefan-ka/protobufgen/issues'
+            }
+            licenses {
+                license {
+                    name 'Apache License 2.0'
+                    url 'https://github.com/stefan-ka/protobufgen/blob/master/LICENSE'
+                    distribution 'repo'
+                }
+            }
+            scm {
+                url 'https://github.com/stefan-ka/protobufgen'
+                connection 'scm:git:git://github.com/stefan-ka/protobufgen.git'
+                developerConnection 'scm:git:ssh://git@github.com:stefan-ka/protobufgen.git'
+            }
+            developers {
+                developer {
+                    name 'Stefan Kapferer'
+                    email 'stefan@kapferer.ch'
+                }
+            }
+        }
+    }
+}
+
 test {
     useJUnitPlatform()
 }
@@ -33,3 +152,15 @@ jacocoTestReport {
 }
 
 check.dependsOn jacocoTestReport
+
+model {
+    tasks.generatePomFileForMavenJavaPublication {
+        destination = file("$buildDir/generated-pom.xml")
+    }
+    tasks.publishMavenJavaPublicationToMavenLocal {
+        dependsOn project.tasks.signArchives
+    }
+    tasks.publishMavenJavaPublicationToMavenRepository {
+        dependsOn project.tasks.signArchives
+    }
+}

gradle.properties

@@ -1,2 +1,7 @@
+# Publication repos
+ossSnapshotRepository=https://oss.sonatype.org/content/repositories/snapshots/
+ossReleaseStagingRepository=https://oss.sonatype.org/service/local/staging/deploy/maven2/
+
+# Dependency versions
 jUnitVersion=5.6.2
 freemarkerVersion=2.3.30