first commit

Author: Kenneth-KT

README.md

@@ -1,2 +1,61 @@
-# parse-js-sdk-iced-coffeescript-patch
-A small patch that adds IcedCoffeeScript style deferral to Parse JS SDK
+# Parse JS SDK IcedCoffeeScript Patch
+A small patch that adds IcedCoffeeScript style deferral to Parse JS SDK.
+
+## Usage
+Compile `parse-iced-patch.iced` with IcedCoffeeScript compiler and include it after including Parse JS SDK.
+You can use it in both Parse Cloud Code and browser client.
+
+It wraps Parse JS SDK methods and generate `X` methods.
+For example, to use `Parse.Object.saveAll()` with Iced syntax, you call `Parse.Object.saveAllX()`.
+
+## Convertion
+Conside this sample code which adds 100 to the field `stock` to all `Product` rows that having `stock == 0`:
+### Original Code
+```coffee
+productQuery = new Parse.Query 'Product'
+productQuery.equalTo 'stock', 0
+productQuery.find
+	success: (products) ->
+		for product in products
+			product.increment 'stock', 100
+		Parse.Object.saveAll products,
+			success: ->
+				console.log 'Completed!'
+			error: ->
+				console.log 'Error!'
+	error: (error) ->
+		console.log 'Error!'
+```
+### After Convertion
+```coffee
+productQuery = new Parse.Query 'Product'
+productQuery.equalTo 'stock', 0
+
+await productQuery.findX defer products, error
+return console.log 'Error!' if error?
+
+for product in products
+	product.increment 'stock', 100
+
+await Parse.Object.saveAllX products, defer result, error
+return console.log 'Error!' if error?
+
+console.log 'Completed!'
+```
+
+## Methods Wrapped
+* Parse.Query.prototype
+  * count
+  * each
+  * find
+  * first
+  * get
+
+* Parse.Object.prototype
+  * destroy
+  * fetch
+  * save
+
+* Parse.Object
+  * destroyAll
+  * saveAll

parse-iced-patch.iced

@@ -0,0 +1,56 @@
+( ->
+
+	promiseToIcedDeferral = (object, funcName) ->
+		overridenFunc = object[funcName]
+		newFunc = ->
+			args = [].slice.call arguments
+			cb = args.pop()
+			promise = overridenFunc.apply this, args
+			promise.then (result) ->
+				cb result, undefined
+			, (error) ->
+				cb undefined, error
+		object[funcName+'X'] = newFunc
+
+	optionsToIcedDeferral = (object, funcName) ->
+		overridenFunc = object[funcName]
+		newFunc = ->
+			args = [].slice.call arguments
+			cb = args.pop()
+
+			options = undefined
+
+			if args.length > 0
+				options = args.pop()
+				if options is undefined or options.constructor isnt Object
+					# not an option hash, push it back
+					args.push options
+					options = undefined
+
+			options = {} if options is undefined
+			options.success = (result) ->
+				cb result, undefined
+			options.error = (error) ->
+				cb undefined, error
+
+			args.push options
+			overridenFunc.apply this, args
+		object[funcName+'X'] = newFunc
+
+
+	['count', 'each', 'find', 'first'].forEach (funcName) ->
+		promiseToIcedDeferral Parse.Query.prototype, funcName
+
+	['destroy', 'fetch', 'save'].forEach (funcName) ->
+		promiseToIcedDeferral Parse.Object.prototype, funcName
+
+	['destroyAll'].forEach (funcName) ->
+		promiseToIcedDeferral Parse.Object, funcName
+
+	['get'].forEach (funcName) ->
+		optionsToIcedDeferral Parse.Query.prototype, funcName
+
+	['saveAll'].forEach (funcName) ->
+		optionsToIcedDeferral Parse.Object, funcName
+
+)()