build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    apply from: 'manifest.gradle'

    ext.kotlinVersion = '1.5.10'
    repositories {
        mavenCentral()
        google()
        maven { url 'https://jitpack.io' }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.2.1'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"

        classpath 'com.vanniktech:gradle-maven-publish-plugin:0.15.1'
    }
}

allprojects {
    repositories {
        mavenCentral()
        google()
    }
    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
    }
    plugins.withId("com.vanniktech.maven.publish") {
        mavenPublish {
            sonatypeHost = "S01"
        }
    }
}

subprojects {
    afterEvaluate {
        if (it.findProperty('publishLibrary') ?: false) {
            plugins.apply('com.vanniktech.maven.publish')
            version = android.defaultConfig.versionName
            println("${it.displayName}: ${group}:${it.name}:${version}")
        }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

ext {
    GROUP = "dev.rikka.shizuku"

    POM_INCEPTION_YEAR = "2021"
    POM_PACKAGING = "aar"

    POM_URL = "https://github.com/RikkaApps/Shizuku-API"
    POM_SCM_URL = "https://github.com/RikkaApps/Shizuku-API"
    POM_SCM_CONNECTION = "scm:git@github.com:RikkaApps/Shizuku-API.git"
    POM_SCM_DEV_CONNECTION = "scm:git@github.com:RikkaApps/Shizuku-API.git"

    POM_LICENCE_NAME = "MIT License"
    POM_LICENCE_URL = "https://github.com/RikkaApps/Shizuku-API/blob/master/LICENSE"
    POM_LICENCE_DIST = "repo"

    POM_DEVELOPER_ID = "rikka"
    POM_DEVELOPER_NAME = "Rikka"
    POM_DEVELOPER_URL = "https://github.com/RikkaW"
}