flake.nix

{
  description = "find-rekeyable tool for reducing rekey sizes";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, rust-overlay, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs { inherit system overlays; };
        rusttoolchain =
          pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
        cargoToml = (builtins.fromTOML (builtins.readFile ./Cargo.toml));

      in
      rec {
        # `nix build`
        packages = {
          find-rekeyable = pkgs.rustPlatform.buildRustPackage {
            pname = cargoToml.package.name;
            version = cargoToml.package.version;
            src = ./.;
            cargoLock.lockFile = ./Cargo.lock;
            nativeBuildInputs = with pkgs;
              [ rusttoolchain ]
              ++ pkgs.lib.optionals pkgs.stdenv.isDarwin
                [ pkgs.darwin.apple_sdk.frameworks.Security ];
          };
          default = packages.find-rekeyable;
        };

        # nix develop
        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs;
            [ rusttoolchain ]
            ++ pkgs.lib.optionals pkgs.stdenv.isDarwin
              [ pkgs.darwin.apple_sdk.frameworks.Security ];
        };

      });
}