-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathARMZ80.s
3975 lines (3880 loc) · 159 KB
/
ARMZ80.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#ifdef __arm__
#include "ARMZ80mac.h"
.syntax unified
.arm
#ifdef Z80_USE_FAST_MEM
#ifdef NDS
.section .itcm ;@ For the NDS ARM9
#elif GBA
.section .iwram, "ax", %progbits ;@ For the GBA
#endif
#else
#ifdef GBA
.section .ewram, "ax" ;@ For the GBA
#else
.section .text ;@ For anything else
#endif
#endif
.align 2
.global Z80Reset
.global Z80SetIRQPin
.global Z80SetNMIPin
.global Z80SetResetPin
.global Z80SetIRQPinCurrentCpu
.global Z80SetNMIPinCurrentCpu
.global Z80SetResetPinCurrentCpu
.global Z80RestoreAndRunXCycles
.global Z80RunXCycles
.global Z80SaveState
.global Z80LoadState
.global Z80GetStateSize
.global Z80RedirectOpcode
.global Z80OpTable
// .global Z80MemWriteTbl
// .global Z80MemReadTbl
.global translateZ80PCToOffset
.global Z80OutOfCycles
.extern Z80In
.extern Z80Out
/*
fetchDebug:
bmi returnToCaller
encodeFLG
and r0,r0,#0xFF
orr z80a,z80a,r0,lsl#16
add z80xy,z80ptr,#z80IX
ldrh r1,[z80xy,#2]
add z80xy,z80xy,#4 ;@ IY
ldrh r2,[z80xy,#2]
// ldr r0,=scanline
// ldr r0,[r0]
loadLastBank r12
sub r12,z80pc,r12
mov r12,r12
b debugContinue
.short 0x6464,0x0000
// .string "AF=%r4% BC=%r5% DE=%r6% HL=%r7% PC=%r12% SP=%r11% IX=%r1% CY=%r8% SL=%r0%"
.string "%r12% AF:%r4% BC:%r5% DE:%r6% HL:%r7% IX:%r1% SP:%r11%"
.align 2
debugContinue:
and z80a,z80a,#0xFF000000
ldrb r0,[z80pc],#1
ldr pc,[z80ptr,r0,lsl#2]
.pool
*/
;@----------------------------------------------------------------------------
_49: ;@ LD C,C
_52: ;@ LD D,D
_5B: ;@ LD E,E
_64: ;@ LD H,H
_6D: ;@ LD L,L
_7F: ;@ LD A,A
;@----------------------------------------------------------------------------
_00: ;@ NOP
;@----------------------------------------------------------------------------
fetch 4
;@----------------------------------------------------------------------------
_01: ;@ LD BC,#nnnn
;@----------------------------------------------------------------------------
opLDIM16
mov z80bc,r0,lsl#16
fetch 10
;@----------------------------------------------------------------------------
_02: ;@ LD (BC),A Write A to (BC)
;@----------------------------------------------------------------------------
mov r0,z80a,lsr#24
writeMem8BC
fetch7_1:
fetch 7
;@----------------------------------------------------------------------------
_03: ;@ INC BC
;@----------------------------------------------------------------------------
opINC16 z80bc
fetch 6
;@----------------------------------------------------------------------------
_04: ;@ INC B
;@----------------------------------------------------------------------------
opINC8H z80bc
fetch 4
;@----------------------------------------------------------------------------
_05: ;@ DEC B
;@----------------------------------------------------------------------------
opDEC8H z80bc
fetch 4
;@----------------------------------------------------------------------------
_06: ;@ LD B,#nn
;@----------------------------------------------------------------------------
opLDIM8H z80bc
fetch 7
;@----------------------------------------------------------------------------
_07: ;@ RLCA Rotate accu left
;@----------------------------------------------------------------------------
bic z80f,z80f,#PSR_n+PSR_H+PSR_C
movs z80a,z80a,lsl#1
orrcs z80a,z80a,#0x01000000
orrcs z80f,z80f,#PSR_C
fetch 4
;@----------------------------------------------------------------------------
_08: ;@ EX AF,AF' Exchange AF & AF'
;@----------------------------------------------------------------------------
add r0,z80ptr,#z80Regs2
swp z80f,z80f,[r0]
add r0,r0,#4
swp z80a,z80a,[r0]
fetch 4
;@----------------------------------------------------------------------------
_09: ;@ ADD HL,BC
;@----------------------------------------------------------------------------
opADD16 z80hl,z80bc
fetch 11
;@----------------------------------------------------------------------------
_0A: ;@ LD A,(BC)
;@----------------------------------------------------------------------------
readMem8BC
mov z80a,r0,lsl#24
fetch 7
;@----------------------------------------------------------------------------
_0B: ;@ DEC BC
;@----------------------------------------------------------------------------
opDEC16 z80bc
fetch 6
;@----------------------------------------------------------------------------
_0C: ;@ INC C
;@----------------------------------------------------------------------------
opINC8L z80bc
fetch 4
;@----------------------------------------------------------------------------
_0D: ;@ DEC C
;@----------------------------------------------------------------------------
opDEC8L z80bc
fetch 4
;@----------------------------------------------------------------------------
_0E: ;@ LD C,#nn
;@----------------------------------------------------------------------------
opLDIM8L z80bc
fetch 7
;@----------------------------------------------------------------------------
_0F: ;@ RRCA Rotate accu right
;@----------------------------------------------------------------------------
bic z80f,z80f,#PSR_n+PSR_H+PSR_C
movs z80a,z80a,lsr#25
orrcs z80f,z80f,#PSR_C
orrcs z80a,z80a,#0x00000080
mov z80a,z80a,lsl#24
fetch 4
;@----------------------------------------------------------------------------
_10: ;@ DJNZ,* Decrease B jump if not zero
;@----------------------------------------------------------------------------
ldrsb r0,[z80pc],#1
sub z80bc,z80bc,#0x01000000
tst z80bc,#0xff000000
addne z80pc,z80pc,r0
subne z80cyc,z80cyc,#5*CYCLE
fetch 8
;@----------------------------------------------------------------------------
_11: ;@ LD DE,#nnnn
;@----------------------------------------------------------------------------
opLDIM16
mov z80de,r0,lsl#16
fetch 10
;@----------------------------------------------------------------------------
_12: ;@ LD (DE),A Write A to (DE)
;@----------------------------------------------------------------------------
mov r0,z80a,lsr#24
writeMem8DE
fetch 7
;@----------------------------------------------------------------------------
_13: ;@ INC DE
;@----------------------------------------------------------------------------
opINC16 z80de
fetch 6
;@----------------------------------------------------------------------------
_14: ;@ INC D
;@----------------------------------------------------------------------------
opINC8H z80de
fetch 4
;@----------------------------------------------------------------------------
_15: ;@ DEC D
;@----------------------------------------------------------------------------
opDEC8H z80de
fetch 4
;@----------------------------------------------------------------------------
_16: ;@ LD D,#nn
;@----------------------------------------------------------------------------
opLDIM8H z80de
fetch 7
;@----------------------------------------------------------------------------
_17: ;@ RLA Rotate accu left through C
;@----------------------------------------------------------------------------
tst z80f,#PSR_C
bic z80f,z80f,#PSR_n+PSR_H+PSR_C
orrne z80a,z80a,#0x00800000
movs z80a,z80a,lsl#1
orrcs z80f,z80f,#PSR_C
fetch 4
;@----------------------------------------------------------------------------
_18: ;@ JR * Relative jump
;@----------------------------------------------------------------------------
ldrsb r0,[z80pc],#1
;@ cmp r0,#-2
;@ andeq z80cyc,z80cyc,#CYC_MASK
add z80pc,z80pc,r0
fetch 12
;@----------------------------------------------------------------------------
_19: ;@ ADD HL,DE
;@----------------------------------------------------------------------------
opADD16 z80hl,z80de
fetch 11
;@----------------------------------------------------------------------------
_1A: ;@ LD A,(DE)
;@----------------------------------------------------------------------------
readMem8DE
mov z80a,r0,lsl#24
fetch 7
;@----------------------------------------------------------------------------
_1B: ;@ DEC DE
;@----------------------------------------------------------------------------
opDEC16 z80de
fetch 6
;@----------------------------------------------------------------------------
_1C: ;@ INC E
;@----------------------------------------------------------------------------
opINC8L z80de
fetch 4
;@----------------------------------------------------------------------------
_1D: ;@ DEC E
;@----------------------------------------------------------------------------
opDEC8L z80de
fetch 4
;@----------------------------------------------------------------------------
_1E: ;@ LD E,#nn
;@----------------------------------------------------------------------------
opLDIM8L z80de
fetch 7
;@----------------------------------------------------------------------------
_1F: ;@ RRA Rotate accu right through C
;@----------------------------------------------------------------------------
orr z80a,z80a,z80f,lsr#1 ;@ Get C
bic z80f,z80f,#PSR_n+PSR_H+PSR_C
movs z80a,z80a,ror#25
orrcs z80f,z80f,#PSR_C
mov z80a,z80a,lsl#24
fetch 4
;@----------------------------------------------------------------------------
_20: ;@ JR NZ,* Jump if not zero
;@----------------------------------------------------------------------------
ldrsb r0,[z80pc],#1
tst z80f,#PSR_Z
subeq z80cyc,z80cyc,#5*CYCLE
addeq z80pc,z80pc,r0
fetch 7
;@----------------------------------------------------------------------------
_21: ;@ LD HL,#nnnn
;@----------------------------------------------------------------------------
opLDIM16
mov z80hl,r0,lsl#16
fetch 10
;@----------------------------------------------------------------------------
_ED63: ;@ LD (NN),HL Write HL to (NN)
;@----------------------------------------------------------------------------
eatCycles 4
;@----------------------------------------------------------------------------
_22: ;@ LD (NN),HL Write HL to (NN)
;@----------------------------------------------------------------------------
ldrb r0,[z80pc],#1
ldrb r1,[z80pc],#1
orr addy,r0,r1,lsl#8
writeMem16 z80hl
fetch 16
;@----------------------------------------------------------------------------
_23: ;@ INC HL
;@----------------------------------------------------------------------------
opINC16 z80hl
fetch 6
;@----------------------------------------------------------------------------
_24: ;@ INC H
;@----------------------------------------------------------------------------
opINC8H z80hl
fetch 4
;@----------------------------------------------------------------------------
_25: ;@ DEC H
;@----------------------------------------------------------------------------
opDEC8H z80hl
fetch 4
;@----------------------------------------------------------------------------
_26: ;@ LD H,#nn
;@----------------------------------------------------------------------------
opLDIM8H z80hl
fetch 7
;@----------------------------------------------------------------------------
_27: ;@ DAA Decimal Adjust Accumulator
;@----------------------------------------------------------------------------
mov r0,#0x60000000
adds r1,r0,z80a,ror#28 ;@ Check low nybble and save top nybble for H check
tstcc z80f,z80f,lsr#5 ;@ PSR_H to carry.
orrcs r0,r0,#0x06
cmn z80a,#0x66000000
tstcc z80f,z80f,lsr#2 ;@ PSR_C to carry.
orrcs r0,r0,#0x60
ands z80f,z80f,#PSR_n ;@ Check if last instruction was add or sub.
orrcs z80f,z80f,#PSR_C ;@ The ands doesn't change carry as long as it doesn't have to shift the immediate value.
rsbne r0,r0,#0
add z80a,z80a,r0,lsl#24
getPzsTbl r2
ldrb r2,[r2,z80a,lsr#24] ;@ Get PZS
orr z80f,z80f,r2
eor r1,r1,z80a,ror#28
tst r1,#0x1
orrne z80f,z80f,#PSR_H
fetch 4
;@----------------------------------------------------------------------------
_28: ;@ JR Z,* Jump if zero
;@----------------------------------------------------------------------------
ldrsb r0,[z80pc],#1
tst z80f,#PSR_Z
subne z80cyc,z80cyc,#5*CYCLE
addne z80pc,z80pc,r0
fetch 7
;@----------------------------------------------------------------------------
_29: ;@ ADD HL,HL
;@----------------------------------------------------------------------------
opADD16_2 z80hl
fetch 11
;@----------------------------------------------------------------------------
_ED6B: ;@ LD HL,(NN) Load HL from (NN)
;@----------------------------------------------------------------------------
eatCycles 4
;@----------------------------------------------------------------------------
_2A: ;@ LD HL,(NN) Load HL from (NN)
;@----------------------------------------------------------------------------
ldrb r0,[z80pc],#1
ldrb r1,[z80pc],#1
orr addy,r0,r1,lsl#8
readMem16 z80hl
fetch 16
;@----------------------------------------------------------------------------
_2B: ;@ DEC HL
;@----------------------------------------------------------------------------
opDEC16 z80hl
fetch 6
;@----------------------------------------------------------------------------
_2C: ;@ INC L
;@----------------------------------------------------------------------------
opINC8L z80hl
fetch 4
;@----------------------------------------------------------------------------
_2D: ;@ DEC L
;@----------------------------------------------------------------------------
opDEC8L z80hl
fetch 4
;@----------------------------------------------------------------------------
_2E: ;@ LD L,#nn
;@----------------------------------------------------------------------------
opLDIM8L z80hl
fetch 7
;@----------------------------------------------------------------------------
_2F: ;@ CPL Complement A
;@----------------------------------------------------------------------------
eor z80a,z80a,#0xFF000000
orr z80f,z80f,#PSR_H|PSR_n ;@ Set H & n
fetch 4
;@----------------------------------------------------------------------------
_30: ;@ JR NC,* Jump if no carry
;@----------------------------------------------------------------------------
ldrsb r0,[z80pc],#1
tst z80f,#PSR_C
subeq z80cyc,z80cyc,#5*CYCLE
addeq z80pc,z80pc,r0
fetch 7
;@----------------------------------------------------------------------------
_31: ;@ LD SP,#nnnn
;@----------------------------------------------------------------------------
opLDIM16
mov z80sp,r0,lsl#16
fetch 10
;@----------------------------------------------------------------------------
_32: ;@ LD (NN),A Write A to (NN)
;@----------------------------------------------------------------------------
ldrb addy,[z80pc],#1
ldrb r0,[z80pc],#1
orr addy,addy,r0,lsl#8
mov r0,z80a,lsr#24
writeMem8
fetch 13
;@----------------------------------------------------------------------------
_33: ;@ INC SP
;@----------------------------------------------------------------------------
opINC16 z80sp
fetch 6
;@----------------------------------------------------------------------------
_34: ;@ INC (HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD34_: ;@ INC (IX+d)
;@----------------------------------------------------------------------------
readMem8
opINC8b
writeMem8
fetch 11
;@----------------------------------------------------------------------------
_35: ;@ DEC (HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD35_: ;@ DEC (IX+d)
;@----------------------------------------------------------------------------
readMem8
opDEC8b
writeMem8
fetch 11
;@----------------------------------------------------------------------------
_36: ;@ LD (HL),#nn
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD36_: ;@ LD (IX+d),#nn
;@----------------------------------------------------------------------------
ldrb r0,[z80pc],#1
writeMem8
fetch 10
;@----------------------------------------------------------------------------
_37: ;@ SCF Set carry flag
;@----------------------------------------------------------------------------
bic z80f,z80f,#PSR_H|PSR_n ;@ Clear H & n
orr z80f,z80f,#PSR_C ;@ Set carry.
fetch 4
;@----------------------------------------------------------------------------
_38: ;@ JR C,* Jump if carry
;@----------------------------------------------------------------------------
ldrsb r0,[z80pc],#1
tst z80f,#PSR_C
subne z80cyc,z80cyc,#5*CYCLE
addne z80pc,z80pc,r0
fetch 7
;@----------------------------------------------------------------------------
_39: ;@ ADD HL,SP
;@----------------------------------------------------------------------------
opADD16 z80hl,z80sp
fetch 11
;@----------------------------------------------------------------------------
_3A: ;@ LD A,(NN) Load A from (NN)
;@----------------------------------------------------------------------------
ldrb addy,[z80pc],#1
ldrb r0,[z80pc],#1
orr addy,addy,r0,lsl#8
readMem8
mov z80a,r0,lsl#24
fetch 13
;@----------------------------------------------------------------------------
_3B: ;@ DEC SP
;@----------------------------------------------------------------------------
opDEC16 z80sp
fetch 6
;@----------------------------------------------------------------------------
_3C: ;@ INC A
;@----------------------------------------------------------------------------
opINC8 z80a
fetch 4
;@----------------------------------------------------------------------------
_3D: ;@ DEC A
;@----------------------------------------------------------------------------
opDEC8 z80a
fetch 4
;@----------------------------------------------------------------------------
_3E: ;@ LD A,#nn
;@----------------------------------------------------------------------------
ldrb r0,[z80pc],#1
mov z80a,r0,lsl#24
fetch 7
;@----------------------------------------------------------------------------
_3F: ;@ CCF Complement carry flag
;@----------------------------------------------------------------------------
bic z80f,z80f,#PSR_H|PSR_n ;@ Clear H & n
tst z80f,#PSR_C
orrne z80f,z80f,#PSR_H ;@ Old carry in H
eor z80f,z80f,#PSR_C ;@ Complement carry.
fetch 4
;@----------------------------------------------------------------------------
;@_40: ;@ LD B,B
;@----------------------------------------------------------------------------
;@ fetch 4
;@----------------------------------------------------------------------------
_41: ;@ LD B,C
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0x00FF0000
orr z80bc,z80bc,z80bc,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_42: ;@ LD B,D
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0x00FF0000
and r0,z80de,#0xFF000000
orr z80bc,z80bc,r0
fetch 4
;@----------------------------------------------------------------------------
_43: ;@ LD B,E
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0x00FF0000
orr z80bc,z80bc,z80de,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_44: ;@ LD B,H
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0x00FF0000
and r0,z80hl,#0xFF000000
orr z80bc,z80bc,r0
fetch 4
;@----------------------------------------------------------------------------
_45: ;@ LD B,L
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0x00FF0000
orr z80bc,z80bc,z80hl,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_46: ;@ LD B,(HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD46_: ;@ LD B,(IX+d)
;@----------------------------------------------------------------------------
readMem8
and z80bc,z80bc,#0x00FF0000
orr z80bc,z80bc,r0,lsl#24
fetch 7
;@----------------------------------------------------------------------------
_47: ;@ LD B,A
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0x00FF0000
orr z80bc,z80bc,z80a
fetch 4
;@----------------------------------------------------------------------------
_48: ;@ LD C,B
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0xFF000000
orr z80bc,z80bc,z80bc,lsr#8
fetch 4
;@----------------------------------------------------------------------------
;@_49: ;@ LD C,C
;@----------------------------------------------------------------------------
;@ fetch 4
;@----------------------------------------------------------------------------
_4A: ;@ LD C,D
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0xFF000000
and r0,z80de,#0xFF000000
orr z80bc,z80bc,r0,lsr#8
fetch 4
;@----------------------------------------------------------------------------
_4B: ;@ LD C,E
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0xFF000000
and r0,z80de,#0x00FF0000
orr z80bc,z80bc,r0
fetch 4
;@----------------------------------------------------------------------------
_4C: ;@ LD C,H
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0xFF000000
and r0,z80hl,#0xFF000000
orr z80bc,z80bc,r0,lsr#8
fetch 4
;@----------------------------------------------------------------------------
_4D: ;@ LD C,L
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0xFF000000
and r0,z80hl,#0x00FF0000
orr z80bc,z80bc,r0
fetch 4
;@----------------------------------------------------------------------------
_4E: ;@ LD C,(HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD4E_: ;@ LD C,(IX+d)
;@----------------------------------------------------------------------------
readMem8
and z80bc,z80bc,#0xFF000000
orr z80bc,z80bc,r0,lsl#16
fetch 7
;@----------------------------------------------------------------------------
_4F: ;@ LD C,A
;@----------------------------------------------------------------------------
and z80bc,z80bc,#0xFF000000
orr z80bc,z80bc,z80a,lsr#8
fetch 4
;@----------------------------------------------------------------------------
_50: ;@ LD D,B
;@----------------------------------------------------------------------------
and z80de,z80de,#0x00FF0000
and r0,z80bc,#0xFF000000
orr z80de,z80de,r0
fetch 4
;@----------------------------------------------------------------------------
_51: ;@ LD D,C
;@----------------------------------------------------------------------------
and z80de,z80de,#0x00FF0000
orr z80de,z80de,z80bc,lsl#8
fetch 4
;@----------------------------------------------------------------------------
;@_52: ;@ LD D,D
;@----------------------------------------------------------------------------
;@ fetch 4
;@----------------------------------------------------------------------------
_53: ;@ LD D,E
;@----------------------------------------------------------------------------
and z80de,z80de,#0x00FF0000
orr z80de,z80de,z80de,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_54: ;@ LD D,H
;@----------------------------------------------------------------------------
and z80de,z80de,#0x00FF0000
and r0,z80hl,#0xFF000000
orr z80de,z80de,r0
fetch 4
;@----------------------------------------------------------------------------
_55: ;@ LD D,L
;@----------------------------------------------------------------------------
and z80de,z80de,#0x00FF0000
orr z80de,z80de,z80hl,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_56: ;@ LD D,(HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD56_: ;@ LD D,(IX+d)
;@----------------------------------------------------------------------------
readMem8
and z80de,z80de,#0x00FF0000
orr z80de,z80de,r0,lsl#24
fetch 7
;@----------------------------------------------------------------------------
_57: ;@ LD D,A
;@----------------------------------------------------------------------------
and z80de,z80de,#0x00FF0000
orr z80de,z80de,z80a
fetch 4
;@----------------------------------------------------------------------------
_58: ;@ LD E,B
;@----------------------------------------------------------------------------
and z80de,z80de,#0xFF000000
and r0,z80bc,#0xFF000000
orr z80de,z80de,r0,lsr#8
fetch 4
;@----------------------------------------------------------------------------
_59: ;@ LD E,C
;@----------------------------------------------------------------------------
and z80de,z80de,#0xFF000000
and r0,z80bc,#0x00FF0000
orr z80de,z80de,r0
fetch 4
;@----------------------------------------------------------------------------
_5A: ;@ LD E,D
;@----------------------------------------------------------------------------
and z80de,z80de,#0xFF000000
orr z80de,z80de,z80de,lsr#8
fetch 4
;@----------------------------------------------------------------------------
;@_5B: ;@ LD E,E
;@----------------------------------------------------------------------------
;@ fetch 4
;@----------------------------------------------------------------------------
_5C: ;@ LD E,H
;@----------------------------------------------------------------------------
and z80de,z80de,#0xFF000000
and r0,z80hl,#0xFF000000
orr z80de,z80de,r0,lsr#8
fetch 4
;@----------------------------------------------------------------------------
_5D: ;@ LD E,L
;@----------------------------------------------------------------------------
and z80de,z80de,#0xFF000000
and r0,z80hl,#0x00FF0000
orr z80de,z80de,r0
fetch 4
;@----------------------------------------------------------------------------
_5E: ;@ LD E,(HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD5E_: ;@ LD E,(IX+d)
;@----------------------------------------------------------------------------
readMem8
and z80de,z80de,#0xFF000000
orr z80de,z80de,r0,lsl#16
fetch 7
;@----------------------------------------------------------------------------
_5F: ;@ LD E,A
;@----------------------------------------------------------------------------
and z80de,z80de,#0xFF000000
orr z80de,z80de,z80a,lsr#8
fetch 4
;@----------------------------------------------------------------------------
_60: ;@ LD H,B
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0x00FF0000
and r0,z80bc,#0xFF000000
orr z80hl,z80hl,r0
fetch 4
;@----------------------------------------------------------------------------
_61: ;@ LD H,C
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0x00FF0000
orr z80hl,z80hl,z80bc,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_62: ;@ LD H,D
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0x00FF0000
and r0,z80de,#0xFF000000
orr z80hl,z80hl,r0
fetch 4
;@----------------------------------------------------------------------------
_63: ;@ LD H,E
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0x00FF0000
orr z80hl,z80hl,z80de,lsl#8
fetch 4
;@----------------------------------------------------------------------------
;@_64: ;@ LD H,H
;@----------------------------------------------------------------------------
;@ fetch 4
;@----------------------------------------------------------------------------
_65: ;@ LD H,L
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0x00FF0000
orr z80hl,z80hl,z80hl,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_66: ;@ LD H,(HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD66_: ;@ LD H,(IX+d)
;@----------------------------------------------------------------------------
readMem8
and z80hl,z80hl,#0x00FF0000
orr z80hl,z80hl,r0,lsl#24
fetch 7
;@----------------------------------------------------------------------------
_67: ;@ LD H,A
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0x00FF0000
orr z80hl,z80hl,z80a
fetch 4
;@----------------------------------------------------------------------------
_68: ;@ LD L,B
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0xFF000000
and r0,z80bc,#0xFF000000
orr z80hl,z80hl,r0,lsr#8
fetch 4
;@----------------------------------------------------------------------------
_69: ;@ LD L,C
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0xFF000000
and r0,z80bc,#0x00FF0000
orr z80hl,z80hl,r0
fetch 4
;@----------------------------------------------------------------------------
_6A: ;@ LD L,D
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0xFF000000
and r0,z80de,#0xFF000000
orr z80hl,z80hl,r0,lsr#8
fetch 4
;@----------------------------------------------------------------------------
_6B: ;@ LD L,E
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0xFF000000
and r0,z80de,#0x00FF0000
orr z80hl,z80hl,r0
fetch 4
;@----------------------------------------------------------------------------
_6C: ;@ LD L,H
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0xFF000000
orr z80hl,z80hl,z80hl,lsr#8
fetch 4
;@----------------------------------------------------------------------------
;@_6D: ;@ LD L,L
;@----------------------------------------------------------------------------
;@ fetch 4
;@----------------------------------------------------------------------------
_6E: ;@ LD L,(HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD6E_: ;@ LD L,(IX+d)
;@----------------------------------------------------------------------------
readMem8
and z80hl,z80hl,#0xFF000000
orr z80hl,z80hl,r0,lsl#16
fetch 7
;@----------------------------------------------------------------------------
_6F: ;@ LD L,A
;@----------------------------------------------------------------------------
and z80hl,z80hl,#0xFF000000
orr z80hl,z80hl,z80a,lsr#8
fetch 4
;@----------------------------------------------------------------------------
_70: ;@ LD (HL),B
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD70_: ;@ LD (IX+d),B
;@----------------------------------------------------------------------------
mov r0,z80bc,lsr#24
writeMem8
fetch 7
;@----------------------------------------------------------------------------
_71: ;@ LD (HL),C
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD71_: ;@ LD (IX+d),C
;@----------------------------------------------------------------------------
mov r0,z80bc,lsr#16
writeMem8
fetch 7
;@----------------------------------------------------------------------------
_72: ;@ LD (HL),D
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD72_: ;@ LD (IX+d),D
;@----------------------------------------------------------------------------
mov r0,z80de,lsr#24
writeMem8
fetch 7
;@----------------------------------------------------------------------------
_73: ;@ LD (HL),E
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD73_: ;@ LD (IX+d),E
;@----------------------------------------------------------------------------
mov r0,z80de,lsr#16
writeMem8
fetch 7
;@----------------------------------------------------------------------------
_74: ;@ LD (HL),H
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD74_: ;@ LD (IX+d),H
;@----------------------------------------------------------------------------
mov r0,z80hl,lsr#24
writeMem8
fetch 7
;@----------------------------------------------------------------------------
_75: ;@ LD (HL),L
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD75_: ;@ LD (IX+d),L
;@----------------------------------------------------------------------------
mov r0,z80hl,lsr#16
writeMem8
fetch 7
;@----------------------------------------------------------------------------
_76: ;@ HALT Wait for interrupt.
;@----------------------------------------------------------------------------
sub z80pc,z80pc,#1
eatCycles 4 ;@ Instruction takes 4 cycles at least
mvns r0,z80cyc,asr#CYC_SHIFT+2 ;@
addmi z80cyc,z80cyc,r0,lsl#CYC_SHIFT+2 ;@ Consume all remaining cycles in steps of 4.
b returnToCaller
;@----------------------------------------------------------------------------
_77: ;@ LD (HL),A
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD77_: ;@ LD (IX+d),A
;@----------------------------------------------------------------------------
mov r0,z80a,lsr#24
writeMem8
fetch 7
;@----------------------------------------------------------------------------
_78: ;@ LD A,B
;@----------------------------------------------------------------------------
and z80a,z80bc,#0xFF000000
fetch 4
;@----------------------------------------------------------------------------
_79: ;@ LD A,C
;@----------------------------------------------------------------------------
mov z80a,z80bc,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_7A: ;@ LD A,D
;@----------------------------------------------------------------------------
and z80a,z80de,#0xFF000000
fetch 4
;@----------------------------------------------------------------------------
_7B: ;@ LD A,E
;@----------------------------------------------------------------------------
mov z80a,z80de,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_7C: ;@ LD A,H
;@----------------------------------------------------------------------------
and z80a,z80hl,#0xFF000000
fetch 4
;@----------------------------------------------------------------------------
_7D: ;@ LD A,L
;@----------------------------------------------------------------------------
mov z80a,z80hl,lsl#8
fetch 4
;@----------------------------------------------------------------------------
_7E: ;@ LD A,(HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD7E_: ;@ LD A,(IX+d)
;@----------------------------------------------------------------------------
readMem8
mov z80a,r0,lsl#24
fetch 7
;@----------------------------------------------------------------------------
;@_7F: ;@ LD A,A
;@----------------------------------------------------------------------------
;@ fetch 4
;@----------------------------------------------------------------------------
_80: ;@ ADD B
;@----------------------------------------------------------------------------
opADDH z80bc
;@----------------------------------------------------------------------------
_81: ;@ ADD C
;@----------------------------------------------------------------------------
opADDL z80bc
;@----------------------------------------------------------------------------
_82: ;@ ADD D
;@----------------------------------------------------------------------------
opADDH z80de
;@----------------------------------------------------------------------------
_83: ;@ ADD E
;@----------------------------------------------------------------------------
opADDL z80de
;@----------------------------------------------------------------------------
_84: ;@ ADD H
;@----------------------------------------------------------------------------
opADDH z80hl
;@----------------------------------------------------------------------------
_85: ;@ ADD L
;@----------------------------------------------------------------------------
opADDL z80hl
;@----------------------------------------------------------------------------
_86: ;@ ADD (HL)
;@----------------------------------------------------------------------------
mov addy,z80hl,lsr#16
;@----------------------------------------------------------------------------
_DD86_: ;@ ADD (IX+d)
;@----------------------------------------------------------------------------
readMem8
opADDb
fetch 7
;@----------------------------------------------------------------------------
_87: ;@ ADD A
;@----------------------------------------------------------------------------
opADDA
;@----------------------------------------------------------------------------
_88: ;@ ADC B
;@----------------------------------------------------------------------------