From f5607906809bf7ba0ec1893ebbcd45ef7442a9b8 Mon Sep 17 00:00:00 2001
From: "brettw@chromium.org"
 <brettw@chromium.org@0039d316-1c4b-4281-b951-d872f2087c98>
Date: Thu, 21 Aug 2014 19:14:57 +0000
Subject: [PATCH] Add apps to the GN build.

Remove duplicate reference of content_switches which causes link errors.

Add dependency on theme_resources from apps (it includes the generated file).

R=miket@chromium.org

Review URL: https://codereview.chromium.org/496763002

Cr-Commit-Position: refs/heads/master@{#291150}
git-svn-id: svn://svn.chromium.org/chrome/trunk/src@291150 0039d316-1c4b-4281-b951-d872f2087c98
---
 BUILD.gn        |  4 +--
 apps/BUILD.gn   | 94 +++++++++++++++++++++++++++++++++++++++++++++++++
 apps/apps.gypi  |  3 ++
 chrome/BUILD.gn |  1 -
 4 files changed, 99 insertions(+), 3 deletions(-)
 create mode 100644 apps/BUILD.gn

diff --git a/BUILD.gn b/BUILD.gn
index 196962aa9bf78d..15084b1545ad35 100644
--- a/BUILD.gn
+++ b/BUILD.gn
@@ -16,8 +16,7 @@ group("root") {
   # currently written but not hooked up to the build yet. They may need to be
   # completed or possibly just tested and then re-enabled.
   deps = [
-    # This is a temporary test of the not-yet-complete NaCl cross-compilation.
-    #"//base(//build/toolchain/nacl:x86_newlib)",
+    "//apps",
     "//ash",
     "//cc",
     "//cc/blink",
@@ -163,6 +162,7 @@ group("root") {
     ]
 
     deps -= [
+      "//apps",  # Needs testing.
       "//cc/blink", # Blocked on blink
       "//chrome/browser",  # Blocked on content.
       "//chrome/browser/devtools",  # Blocked on content.
diff --git a/apps/BUILD.gn b/apps/BUILD.gn
new file mode 100644
index 00000000000000..ececd7dfb57a6b
--- /dev/null
+++ b/apps/BUILD.gn
@@ -0,0 +1,94 @@
+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/features.gni")
+import("//build/config/ui.gni")
+
+static_library("apps") {
+  sources = [
+    "app_lifetime_monitor.cc",
+    "app_lifetime_monitor.h",
+    "app_lifetime_monitor_factory.cc",
+    "app_lifetime_monitor_factory.h",
+    "app_load_service.cc",
+    "app_load_service.h",
+    "app_load_service_factory.cc",
+    "app_load_service_factory.h",
+    "app_restore_service.cc",
+    "app_restore_service.h",
+    "app_restore_service_factory.cc",
+    "app_restore_service_factory.h",
+    "app_window.cc",
+    "app_window.h",
+    "app_window_contents.cc",
+    "app_window_contents.h",
+    "app_window_registry.cc",
+    "app_window_registry.h",
+    "browser_context_keyed_service_factories.cc",
+    "browser_context_keyed_service_factories.h",
+    "custom_launcher_page_contents.cc",
+    "custom_launcher_page_contents.h",
+    "launcher.cc",
+    "launcher.h",
+    "metrics_names.h",
+    "pref_names.cc",
+    "pref_names.h",
+    "prefs.cc",
+    "prefs.h",
+    "saved_files_service.cc",
+    "saved_files_service.h",
+    "saved_files_service_factory.cc",
+    "saved_files_service_factory.h",
+    "switches.cc",
+    "switches.h",
+    "ui/apps_client.cc",
+    "ui/apps_client.h",
+    "ui/web_contents_sizer.h",
+  ]
+
+  configs += [ "//build/config/compiler:wexit_time_destructors" ]
+
+  deps = [
+    "//chrome/app/theme:theme_resources",
+    "//chrome/browser/extensions",
+    "//chrome/common/extensions/api:api",
+    "//skia",
+  ]
+
+  if (is_chromeos) {
+    #deps += [ "browser_chromeos" ]  TODO(GYP)
+  }
+
+  if (!enable_extensions) {
+    # When extensions are disabled, only the sizer file below is included.
+    deps -= [ "//chrome/browser/extensions" ]
+    sources = []
+  }
+
+  # This needs to run after the extensions check above since we always want
+  # this file in the project.
+  if (is_mac) {
+    sources += [ "ui/web_contents_sizer.mm" ]
+  } else {
+    sources += [ "ui/web_contents_sizer.cc" ]
+  }
+
+  if (toolkit_views) {
+    sources += [
+      "ui/views/app_window_frame_view.cc",
+      "ui/views/app_window_frame_view.h",
+      "ui/views/native_app_window_views.cc",
+      "ui/views/native_app_window_views.h",
+    ]
+    deps += [
+      "//ui/strings",
+      "//ui/views",
+    ]
+  }
+
+  if (is_win) {
+    # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
+    cflags = [ "/wd4267" ]
+  }
+}
diff --git a/apps/apps.gypi b/apps/apps.gypi
index 73a288ff559dc8..608b919a20b886 100644
--- a/apps/apps.gypi
+++ b/apps/apps.gypi
@@ -5,6 +5,7 @@
 {
   'targets': [
     {
+      # GN version: //apps
       'target_name': 'apps',
       'type': 'static_library',
       'variables': { 'enable_wexit_time_destructors': 1, },
@@ -15,6 +16,7 @@
       # browser, then we can clean up these dependencies.
       'dependencies': [
         'browser_extensions',
+        'chrome_resources.gyp:theme_resources',
         'common/extensions/api/api.gyp:chrome_api',
         '../skia/skia.gyp:skia',
       ],
@@ -23,6 +25,7 @@
         '<(grit_out_dir)',
       ],
       'sources': [
+        # Note: file list duplicated in GN build.
         'app_lifetime_monitor.cc',
         'app_lifetime_monitor.h',
         'app_lifetime_monitor_factory.cc',
diff --git a/chrome/BUILD.gn b/chrome/BUILD.gn
index 04d37bb9d6240a..6a687409030544 100644
--- a/chrome/BUILD.gn
+++ b/chrome/BUILD.gn
@@ -15,7 +15,6 @@ source_set("chrome") {
   # removing unused files.
   sources = [
     "app/chrome_exe_resource.h",
-    "//content/public/common/content_switches.cc",
   ]
   deps = []