build.gradle

import net.fabricmc.loom.task.RunClientTask
import net.fabricmc.loom.task.RunServerTask
import org.apache.tools.ant.filters.ReplaceTokens

buildscript {
    dependencies {
        classpath fileTree(dir: "libs", include: "fabric-loom-0.7.local.jar")
    }
}

plugins {
    id 'maven-publish'
    id 'fabric-loom' version "0.7-SNAPSHOT"
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
    maven {
        name = 'legacy-fabric'
        url = 'https://maven.legacyfabric.net'
    }
    maven {
        url 'https://jitpack.io'
    }
    maven {
        name 'HalfOf2'
        url 'https://storage.googleapis.com/devan-maven/'
    }
}

sourceSets {
    btw {
        java {
            srcDirs = ['src/btw/java']
        }
        resources {
            srcDirs = ['src/btw/resources']
        }
    }
}

def lwjglVersion = System.getProperty("os.name").toLowerCase().contains("mac") ? "2.9.1" : "2.9.0"

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    implementation 'org.apache.logging.log4j:log4j-core:2.17.0'
    implementation 'org.apache.logging.log4j:log4j-api:2.17.0'

    implementation "org.lwjgl.lwjgl:lwjgl_util:${lwjglVersion}"
    implementation "org.lwjgl.lwjgl:lwjgl:${lwjglVersion}"
    implementation "org.lwjgl.lwjgl:lwjgl-platform:${lwjglVersion}"

    implementation fileTree(dir: "libs", include: "**.zip")
    compileOnly fileTree(dir: "$projectDir/BTW_dev", include: "*.zip")
    compileOnly fileTree(dir: "$buildDir/BTW_dev", include: "**.jar")

    runtimeClasspath fileTree(dir: "$buildDir/dev_run", include: "dev.jar")

    mappings fileTree(dir: "custom_mappings", include: "**.zip")
    modImplementation("io.github.minecraft-cursed-legacy:cursed-fabric-loader:${loader_version}") {
        transitive false
    }
}

configurations {
    btwCompileClasspath.extendsFrom implementation, modImplementation
}

configurations.all {
    resolutionStrategy {
        dependencySubstitution {
            substitute module('org.lwjgl.lwjgl:lwjgl_util:2.9.1-nightly-20130708-debug3') with module("org.lwjgl.lwjgl:lwjgl_util:${lwjglVersion}")
            substitute module('org.lwjgl.lwjgl:lwjgl:2.9.1-nightly-20130708-debug3') with module("org.lwjgl.lwjgl:lwjgl:${lwjglVersion}")
        }
        force "org.lwjgl.lwjgl:lwjgl-platform:${lwjglVersion}"
    }
}

processResources {
    inputs.property "version", project.version
    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"
    if (JavaVersion.current().isJava9Compatible()) it.options.release = 8
}

java {
    withSourcesJar()
}

task processSource(type: Sync) {
    from sourceSets.main.java
    inputs.property 'version', project.version
    inputs.property 'name', project.name
    inputs.property 'prefix', project.prefix
    filter(ReplaceTokens, tokens: [VERSION: project.version, NAME: project.name, PREFIX: project.prefix])
    into "$buildDir/src"
}

compileJava {
    dependsOn('btwJar')
    source = processSource.outputs
}

task devPackMod(type:Copy) {
    dependsOn('jar')
    from sourceSets.main.output.classesDirs
    into file("$buildDir/classes/java/btw")
}

task devPackBTW(type:Copy) {
    dependsOn('devPackMod')
    dependsOn('btwJar')
}

task devPackRun(type:Jar) {
    dependsOn('devPackBTW')
    from fileTree("$buildDir/classes/java/btw")
    from fileTree("$projectDir/BTW_dev/")
    from sourceSets.btw.output.resourcesDir
    destinationDirectory = file("$buildDir/dev_run")
    archiveFileName = "dev.jar"
}

jar {
    from sourceSets.main.output.resourcesDir
    from sourceSets.main.output.classesDirs
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}"}
    }
}

task btwJar(type:Jar) {
    from fileTree("$projectDir/BTW_dev/")
    from sourceSets.btw.output.resourcesDir
    from sourceSets.btw.output.classesDirs
    destinationDirectory = file("$buildDir/BTW_dev")
    archiveFileName = "BTW_dev.jar"
}

remapJar {
    dependsOn(jar)
    input.set jar.archiveFile.get()
    destinationDirectory = file("$rootDir/release")
}

reobfuscateJar {
    dependsOn(jar)
    input.set jar.archiveFile.get()
    destinationDirectory = file("$rootDir/reobfuscated")
}

task safeRunClient(type:RunClientTask) {
    mustRunAfter('clean')
    dependsOn('clean')
    dependsOn('devPackRun')
}

task safeRunServer(type:RunServerTask) {
    mustRunAfter('clean')
    dependsOn('clean')
    dependsOn('devPackRun')
}

runClient {
    dependsOn('devPackRun')
}

runServer {
    dependsOn('devPackRun')
}

clean.doFirst {
    delete "$buildDir/dev_run"
    delete "$buildDir/BTW_dev"
}