Help with my conditions

[GBCSIM1]

When trying to deploy Recovery Services Vault in our landing zone repo.

My module is this:

module RecoveryServicesVault 'modules/recovery-services.bicep' = [ for subnet in subnetArray: if (createBackup == true && contains(subnet.subnetName , 'backup'))  {
  scope: resourceGroupBackup
  name: '${pipelineId}-recoveryServicesVault_${subnet.subnetName}'
  params: {
    environmentType:environmentType
    subnetId: backup_subnet.id
    location: location
    recoveryServiceVaultName: recoveryServicesName
    publicNetworkAccess: 'Disabled'
    logAnalytics:  (operationType == 'Create' && location == 'westeurope') ? logAnalyticscreate.outputs.id : (operationType == 'Update' && location == 'westeurope') ? logAnalyticsUpdate.outputs.id : logAnalytics.outputs.id
    rgBackupName: resourceGroupBackup.name
}
}
]

The problem i have now that the name
name: '${pipelineId}-recoveryServicesVault_${subnet.subnetName}'

Doesn't just pick up the "Backup" subnet it also tries to do others in our list too.

Is there anyway my condition can specify the Backup subnet.

This deploys the Backup Subnet and then tries with the mgmt subnet.
This is the Pipeline error.
Deployment '873574-recoveryServicesVault_mgmt' could not be found. (Code: DeploymentNotFound)

[GABRIELNGBTUC]

Are you doing something like this?

var arrayList = [
  'value1'
  'value2'
  'value3'
]

module module2 './module2.bicep' = [ for item in arrayList: if(item != 'value2') {
  name: 'module2-${item}'
}
] 

// Forgot the if condition
output moduleOutputs array = [ for (mod, i) in arrayList: {
  item: arrayList[i]
  output: module2[i].outputs.someOutput
} ]

The error message Deployment '873574-recoveryServicesVault_mgmt' could not be found. (Code: DeploymentNotFound) implies that you are trying to access outputs of the module array at an index that does not exist. You should check that every single iteration manipulating the module RecoveryServicesVault is following the same if condition used to create it. Or simpler, instead of applying a conditional at the module level, encapsulate it inside a variable so that it is easier to use in your file. Example:

var arrayList = [
  'value1'
  'value2'
  'value3'
]

var filteredArrays = filter(arrayList, item => item != 'value2')

module module2 './module2.bicep' = [ for item in filteredArrays: {
  name: 'module2-${item}'
}
] 

// If condition no longer needed
output moduleOutputs array = [ for (mod, i) in filteredArrays: {
  item: filteredArrays[i]
  output: module2[i].outputs.someOutput
} ]