forked from onvif/specs
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathdocbook.xsl
368 lines (340 loc) · 12.5 KB
/
docbook.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:db="http://docbook.org/ns/docbook" xmlns="http://www.w3.org/1999/xhtml">
<xsl:output encoding="UTF-8" indent="no" media-type="text/html" method="html" />
<xsl:variable name="css">
body{
background-color: #d0d0d0;
}
.page {
background-color: #ffffff;
font-family:Arial,Helvetica;
font-size:10pt;
width: 21cm;
text-align: center;
margin-left: auto;
margin-right: auto;
}
.pages {
text-align: left;
padding: 30mm 30mm 30mm 30mm;
}
div {
margin-bottom: 5mm;
}
li {
margin-top: 2.5mm;
}
pre {
font-size:9pt;
}
td {
vertical-align: top
}
.heading {
font-size:20pt;
text-align: center;
margin-left: auto;
margin-right: auto;
}
.plaindiv {
margin-bottom: 0mm;
}
.version {
font-size:12pt;
text-align: center;
margin-left: auto;
margin-right: auto;
}
.h2 {
font-size:14pt;
}
.param, .access {
font-weight: bold;
margin-left: 15mm;
margin-top: 1.5mm;
margin-bottom: 1mm;
}
.text {
margin-left: 15mm;
margin-top: 0mm;
margin-bottom: 3mm;
}
.reference {
margin-top: 0mm;
}
.figure {
font-weight: bold;
text-align: center;
}
abbr[title] {
text-decoration: none;
}
.op {
text-transform: uppercase;
margin-bottom: 0mm;
}
.table {
text-align: center;
}
.table>table, .table>table>thead>tr>th, .table>table>tbody>tr>td {
text-align: left;
border: 1px solid black;
border-collapse: collapse;
padding: 1mm 3mm 1mm 3mm;
}
.table>table>thead>tr>th {
background-color: #d0d0d0;
font-weight: bold;
}</xsl:variable>
<xsl:template match="/">
<html>
<head>
<style type="text/css">
<xsl:value-of select="$css" disable-output-escaping="yes"/>
</style>
</head>
<body>
<div class="page">
<div class="pages">
<xsl:apply-templates/>
</div>
</div>
</body>
</html>
</xsl:template>
<xsl:template match="db:book">
<div class='heading'><xsl:value-of select="db:info/db:author/db:orgname"/></div>
<div class='heading'><xsl:value-of select="db:info/db:title"/></div>
<div class='version'>Working Draft <xsl:value-of select="db:info/db:releaseinfo"/></div>
<div class='version'><xsl:value-of select="db:info/db:pubdate"/></div>
<div class='version'><img src="media/logo.png" style="width:60mm"/></div>
<div><xsl:value-of select="db:info/db:legalnotice"/></div>
<xsl:apply-templates select="db:chapter|db:appendix" />
</xsl:template>
<xsl:template match="db:info|db:title[parent::db:section|parent::db:chapter|parent::db:appendix]">
</xsl:template>
<!-- Headings -->
<xsl:template match="db:chapter|db:section">
<xsl:element name="div">
<h2>
<xsl:apply-templates select="@xml:id"/>
<xsl:apply-templates select="." mode="number"/>
<xsl:value-of select="db:title"/>
</h2>
</xsl:element>
<xsl:apply-templates />
</xsl:template>
<xsl:template match="db:section|db:chapter|db:appendix" mode="number">
<xsl:choose>
<xsl:when test="ancestor-or-self::db:appendix">
<xsl:number level="multiple" count="db:appendix|db:section" format="A.1 "/>
</xsl:when>
<xsl:otherwise>
<xsl:number level="multiple" count="db:chapter|db:section" format="1.1 "/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="db:appendix">
<xsl:element name="div">
<xsl:apply-templates select="@xml:id"/>
<xsl:attribute name="style">margin-top:30mm; text-align:center</xsl:attribute>
<h2>Annex <xsl:number level="multiple" count="db:appendix" format="A.1 "/> <xsl:value-of select="db:title"/></h2>
</xsl:element>
<xsl:apply-templates />
<xsl:if test="@role='revhistory'">
<div class='table'><table><thead>
<tr>
<th>Rev.</th><th>Date</th><th>Author</th><th>Changes</th>
</tr>
</thead>
<tbody>
<xsl:for-each select="/db:book/db:info/db:revhistory/db:revision">
<tr>
<td><xsl:value-of select="db:revnumber"/></td>
<td><xsl:value-of select="db:date"/></td>
<td><xsl:value-of select="db:author"/></td>
<td><xsl:value-of select="db:revremark"/></td>
</tr>
</xsl:for-each>
</tbody></table></div>
</xsl:if>
</xsl:template>
<!-- Paragraph -->
<xsl:template match="db:emphasis[@role='bold']">
<b><xsl:value-of select="."/></b>
</xsl:template>
<xsl:template match="db:para[not(@role)]">
<div><xsl:apply-templates/></div>
</xsl:template>
<xsl:template match="db:term[ancestor::db:variablelist[@role='op']]">
<div class='op'><xsl:value-of select="."/>:</div>
</xsl:template>
<!-- Lists -->
<xsl:template match="db:para[@role]">
<xsl:element name="div">
<xsl:attribute name="class"><xsl:value-of select="@role"/></xsl:attribute>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="db:variablelist[not(@role)]">
<table><tbody>
<xsl:for-each select="db:varlistentry">
<tr>
<td class='param'><xsl:value-of select="db:term"/></td>
<td><xsl:apply-templates select="db:listitem"/></td>
</tr>
</xsl:for-each>
</tbody></table>
</xsl:template>
<xsl:template match="db:itemizedlist">
<ul>
<xsl:for-each select="db:listitem">
<li>
<xsl:apply-templates select="db:para" mode="plaindiv"/>
</li>
</xsl:for-each>
</ul>
</xsl:template>
<xsl:template match="db:para" mode="plaindiv">
<div class="plaindiv"><xsl:apply-templates/></div>
</xsl:template>
<!-- Tables -->
<xsl:template match="db:informaltable">
<table>
<xsl:apply-templates select="db:tgroup/db:tbody/db:row"/>
</table>
</xsl:template>
<xsl:template match="db:table">
<xsl:element name="div">
<xsl:attribute name="class">table</xsl:attribute>
<xsl:apply-templates select="@xml:id"/>
<xsl:element name="table">
<xsl:element name="thead">
<xsl:apply-templates select="db:tgroup/db:thead/db:row"><xsl:with-param name="header" select="'1'"/></xsl:apply-templates>
</xsl:element>
<xsl:element name="tbody">
<xsl:apply-templates select="db:tgroup/db:tbody/db:row"/>
</xsl:element>
</xsl:element>
</xsl:element>
<xsl:element name="div">
<xsl:attribute name="class">figure</xsl:attribute>
Table <xsl:number count="db:table" level="any" format="1"/>: <xsl:value-of select="db:title"/>
</xsl:element>
</xsl:template>
<xsl:template match="db:row">
<xsl:param name="header"/>
<tr>
<xsl:apply-templates select="db:entry"><xsl:with-param name="header" select="$header"></xsl:with-param></xsl:apply-templates>
</tr>
</xsl:template>
<xsl:template match="db:entry">
<xsl:param name="header"/>
<xsl:variable name="cell"><xsl:choose>
<xsl:when test="$header='1'">th</xsl:when>
<xsl:otherwise>td</xsl:otherwise>
</xsl:choose></xsl:variable>
<xsl:element name="{$cell}">
<xsl:if test="@morerows">
<xsl:attribute name="rowspan"><xsl:value-of select="@morerows + 1"/></xsl:attribute>
</xsl:if>
<xsl:variable name="colspan" select="1 + number(substring(@nameend, 2)) - number(substring(@namest, 2))"/>
<xsl:if test="$colspan > 1">
<xsl:attribute name="colspan"><xsl:value-of select="$colspan"/></xsl:attribute>
</xsl:if>
<xsl:if test="@align">
<xsl:attribute name="style"><xsl:value-of select="concat('text-align:', @align)"/></xsl:attribute>
</xsl:if>
<xsl:apply-templates select="db:para" mode="plain"/>
</xsl:element>
</xsl:template>
<xsl:template match="db:para" mode="plain">
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="db:title[parent::db:table|parent::db:figure]">
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="db:superscript">
<sup>
<xsl:apply-templates/>
</sup>
</xsl:template>
<xsl:template match="db:emphasis[@role=bold]">
<b>
<xsl:apply-templates/>
</b>
</xsl:template>
<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>
<!-- Figures-->
<xsl:template match="db:figure">
<div class="figure">
<xsl:element name="img">
<xsl:apply-templates select="@xml:id"/>
<xsl:attribute name="src"><xsl:value-of select="db:mediaobject/db:imageobject/db:imagedata/@fileref"/></xsl:attribute>
<xsl:attribute name="style">width:<xsl:value-of select="db:mediaobject/db:imageobject/db:imagedata/@contentwidth"/></xsl:attribute>
</xsl:element>
</div>
<div class="figure">
Figure <xsl:number count="db:figure" level="any" format="1"/>: <xsl:apply-templates select="db:title"/>
</div>
</xsl:template>
<xsl:template match="@xml:id">
<xsl:attribute name="id"><xsl:value-of select="."/></xsl:attribute>
</xsl:template>
<xsl:template match="db:inlinemediaobject">
<xsl:element name="img">
<xsl:attribute name="src"><xsl:value-of select="db:imageobject/db:imagedata/@fileref"/></xsl:attribute>
<xsl:if test="db:textobject">
<xsl:apply-templates select="db:textobject" />
</xsl:if>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="db:programlisting">
<pre>
<xsl:apply-templates/>
</pre>
</xsl:template>
<xsl:template match="db:footnote">
<xsl:element name="abbr">
<xsl:attribute name="title"><xsl:value-of select="."/></xsl:attribute><sup><xsl:number count="db:footnote" level="any" format="1"/></sup>
</xsl:element>
</xsl:template>
<!-- References -->
<xsl:template match="db:xref">
<xsl:variable name="id"><xsl:value-of select="@linkend"/></xsl:variable>
<xsl:variable name="target" select="//*[@xml:id=$id]"/>
<xsl:element name="a">
<xsl:attribute name="href">#<xsl:copy-of select="$id"/></xsl:attribute>
<xsl:apply-templates mode="ref" select="$target"/>
</xsl:element>
</xsl:template>
<xsl:template match="db:section|db:chapter|db:appendix" mode="ref">
<xsl:choose>
<xsl:when test="ancestor-or-self::db:appendix">
Annex <xsl:number level="multiple" count="db:appendix|db:section" format="A.1 "/>
</xsl:when>
<xsl:otherwise>
<xsl:number level="multiple" count="db:chapter|db:section" format="1.1 "/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="db:table" mode="ref">
Table <xsl:number count="db:table" level="any" format="1"/>
</xsl:template>
<xsl:template match="db:figure" mode="ref">
Figure <xsl:number count="db:figure" level="any" format="1"/>
</xsl:template>
<xsl:template match="db:link">
<xsl:element name="a">
<xsl:attribute name="href"><xsl:value-of select="@xlink:href"/></xsl:attribute>
<xsl:attribute name="target">new</xsl:attribute>
<xsl:if test="not(text())"><xsl:value-of select="@xlink:href"/></xsl:if>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
</xsl:stylesheet>